一、函式引數使用錯誤。

第1種：第2個引數區域設定錯誤之1。

錯誤原因: vlookup函式第二個引數是查詢區域，該區域的第1列有一個必備條件，就是查詢的物件（A9），必須對應於區域的第1列。本例中是根據姓名查詢的，那麼，第二個引數姓名必須是在區域的第1列位置，而上述公式中姓名列是在區域A1：E6的第2列。所以公式應改為：

=VLOOKUP(A9,B1:E6,3,0)

第2種：第2個引數區域設定錯誤之2。

例2 如下圖所示根據姓名查詢職務時產生查詢錯誤。

錯誤原因：本例是根據姓名查詢職務，可大家注意一下，第2個引數B1:D6根本就沒有包括E列的職務，當然會產生錯誤了。所以公式應改為：

=VLOOKUP(A9,B1:E6,4,0)

第3種：第4個引數少了或設定錯誤。

例3，如下圖所示根據工號查詢姓名

錯誤原因：vlookup第四個引數為0時表示精確查詢，為1或省略時表示模糊查詢。如果忘了設定第4個引數則會被公式誤以為是故意省略，按模糊查詢進行。當區域也不符合模糊查詢規則時，公式就會返回錯誤值。所以公式應改為。

=VLOOKUP(A9,A1:D6,2,0)

或 =VLOOKUP(A9,A1:D6,2,) 注：當引數為0時可以省略，但必須保留“,”號。

蘭色說：今天所介紹的1~3錯誤是最簡單的查詢錯誤，可能有些同學已能輕鬆處理，明天咱們繼續介紹VLOOKUP函式的其他查詢錯誤，可能你處理起來就沒這麼輕鬆了。

二、數字格式不同，造成查詢錯誤。

第4種 查詢為數字，被查詢區域為文字型數字。

例4：如下圖所示根據工號查詢姓名，查找出現錯誤。

錯誤原因：在vlookup函式查詢過程中，文字型數字和數值型數字會被認為不同的字元。所以造成無法成功查詢。

解決方案：把查詢的數字在公式中轉換成文字型，然後再查詢。即：

=VLOOKUP(A9&"",A1:D6,2,0)

第5種 查詢格式為文字型數字，被查詢區域為數值型數字。

例5：如下圖所示根據工號查詢姓名，查找出現錯誤

錯誤原因：同4

解決方法：把文字型數字轉換成數值型。即：

=VLOOKUP(A9*1,A1:D6,2,0)

三、引用方式使公式複製後產生錯誤。

第6種 沒有正確的使用引用方式，造成在複製公式後區域發生變動引起錯誤。

例6，如下圖所示，當C9的公式複製到C10和C11後，C10公式返回錯誤值。

錯誤原因：由於第二個引數A2:D6是相對引用，所以向下複製公式後會自動更改為A3:D7,而A10中的工號A01所在的行，不在A3:D7區域中，從而造成查詢失敗。

解決方案：把第二個引數的引用方式由相對引用改為絕對引用即可。

B9公式改為：=VLOOKUP(A9,$A$2:$D$6,2,0）

四、多餘的空格或不可見字元

第7種 資料表中含有多餘的空格。

例7 如下圖所示，由於A列工號含有多餘的空格，造成查詢錯誤。

錯誤原因：多一個空格，用不帶空格的字元查詢當然會出錯了。

解決方案: 1 手工替換掉空格。建議用這個方法

2 在公式中用trim函式替換空格而必須要用資料公式形式輸入。

即：=VLOOKUP(A9,TRIM(A1:D6),2,0) 按ctrl+shift+enter輸入後陣列形式為 {=VLOOKUP(A9,TRIM(A1:D6),2,0)}

第8種：類空格但非空格的字元。

在表格存在大量的“空格”，但又用空格無法替換掉時，這些就是類空格的不可見字元，這時可以“以其人之道還之其人之身”，直接在單元格中複製不可見字元貼上到替換視窗，替換掉即可。

第9種：不可見字元的影響

例： 如下圖所示的A列中，A列看不去不存在空格和類空格字元，但查詢結果還是出錯。

出錯原因：這是從網頁或資料庫中匯入資料時帶來的不可見字元，造成了查詢的錯誤。

解決方案：在A列後插入幾列空列，然後對A列進行分列操作（資料 - 分列），即可把不可見字元分離出去。

大家好，今天和大家分享"Vlookup函式V不出來"，來自一朋友的提問，為什麼我根據工號查詢部門報錯，D列是程式碼，E列是代表的部門，工號的前3位決定是那個部門，如下圖

一、原因分析

這位朋友沒有理解是什麼是數值型數字，什麼是文字型數字？在Excel裡分2種，一種是文字型數字，一種是數值型數字，文字型數字沒有大小之分，數值型數字有大小之分，另外一點，文字函式如Left,Right,Mid這一類提取出來的是文字型的，而你資料來源D列的程式碼又是數值型的數字導致Vlookup函式報錯

二、解決方法

我們可以透過--，這種減負運算把文字型數字轉數值型數字，當然我們也可以透過分列把D列數值型轉為文字型，目的就是A列和D列的格式一致。

1、公式截圖

2、公式

=VLOOKUP(--LEFT(A2,3),D:E,2,0)

3、公式解釋

從左邊提取3位作vookup函式的第1引數查詢值，由於第2引數資料來源的D列是數值型數，所以要在left前加負負--，把文字型轉數值型

vlookup4個引數，第1引數查詢值；第2引數資料來源；第3引數返回資料來源那一列；第4引數用0精確查詢

VLOOKUP函式是日常運用中最常用函式之一，之所以容易出錯，一般是大量資料，多列查詢，沒有鎖定資料引用範圍；或者是查詢資料的與輸入值格式不一致造成。

VLOOKUP基本格式：VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

基本格式是從左到右查詢，即在資料來源中，查詢結果必須在輸入值的右邊。

但是，如果我們按vlookup基本格式用標籤來查詢排序，就會出錯了，這時可以引入一個排序函式{1,0}，就可以達到效果。

vlookup函式如何查詢右邊內容？

上圖，排序位於標籤左側，這時用排序函式先將二者順序調換，再查詢，即可查找出準確的結果：

=VLOOKUP(D3,IF({1,0},B:B,A:A),2,0)

學好vlookup等幾個基本函式，瞭解其簡單套路，那麼就能解決日常大部分需求了。

專業從事查詢功能的函式：Vlookup，引數眾多，“脾氣”暴躁，規則複雜，一不留心就會出錯。

出錯誤並不可怕，怕的是不知道怎麼解決。

本文就教你破解VLOOKUP函式病症的良藥。

▼

在總結Vlookup函式錯誤之前，我們先來回顧下Vlookup函式的語法：

VLOOKUP(lookup_value, table_array, col_index_num, [range_lookup])

即VLOOKUP(查詢物件，查詢範圍，返回列數，精確匹配或者近似匹配）

入門|快速掌握VLOOKUP函式之精解精析

進階|熟練使用VLOOKUP函式之精解精析【深度長文】

— 01 —

引數使用錯誤

NO.1:引數1使用錯誤

通常對於批次查詢，引數1會使用引用單元格，這就涉及到引用方式的問題，稍微不注意，就可能造成查詢錯誤。

比如，在F2輸入公式=VLOOKUP($E$2,B:C,2,0)，向下複製填充，結果三個單元格中返回的值都是89，顯然高書記和李書記的成績是錯誤的。

錯誤原因：第一個引數採用了絕對引用，這樣在複製填充時，單元格引用不會變化，所以一直查詢的是“陸亦可”對應的成績。

解決方法：對於VLOOKUP的第一個引數，如果公式需要向下複製填充，則需要使用行的相對引用，使查詢物件可以依次變更。所以公式改為=VLOOKUP($E2,B:C,2,0)或=VLOOKUP(E2,B:C,2,0)均可。

NO.2:引數2首行錯誤

VLOOKUP函式中，引數2的限制很多，是最容易出錯的地方。如圖查詢三位同事的成績，結果均返回錯誤值。

錯誤原因：VLOOKUP函式的第二個引數是查詢區域，這個區域不是隨便選取的，它必須滿足的條件之一就是：引數1（查詢物件）必須位於該區域的第1列。

本例選取的引數2為A:C，其中姓名列位於此區域的第二列，所以無法正確查詢。

解決方法：將公式修改為=VLOOKUP(E2,B:C,2,0)，即函式的第二個引數設定為B:C。

NO.3:引數2區域範圍錯誤

如圖所示，引數2設定為B:C，可是查詢還是出錯了。

錯誤原因：引數2必須滿足的條件之二就是：這個區域一定要包含需要返回的值所在的列。我們需要返回成績，但是第2個引數B:C根本就沒有包括需要返回值所在的D列。

解決方法：將公式修改為=VLOOKUP(F2,B:D,3,0)，使第二引數包含需要返回的值。

NO.4：引數2區域中列的順序錯誤

如圖，使用姓名查詢組別，結果返回錯誤值。

錯誤原因：本例中VLOOKUP函式的第二引數為A:B，其實這裡有兩個錯誤。一是引數1並不在引數2選定區域的第一列；第二是返回值“組別”在查詢值的左側，這是不允許的。

解決方法：①最簡單的方法，將A、B列資料互換，然後再使用VLOOKUP查詢；②使用index+match組合查詢，詳細見這篇文章中關於INDEX和MATCH函式的講解：

從0到1：混職場，必須掌握的十二個Excel函式

NO.5：引數3使用錯誤

引數3：“返回的列數”指的是在引數2這個區域中的列數，它不一定等於在Excel表格中的列數，如圖錯誤將引數3的值設定為“4”，結果返回錯誤值。

錯誤原因：成績位於引數2選定的區域“B:D”中的第三列，而不是第四列，因此引數3需要設定為3.

解決方法：將公式修改為=VLOOKUP(F2,B:D,3,0)即可。

NO.6：引數4設定錯誤

如圖所示，最後一個引數設定為1，結果返回的數值與姓名對不上號。

錯誤原因：VLOOKUP函式的引數4為0或省略時表示精確查詢，非0值時表示模糊查詢。這裡設定為1，所以進行的是模糊查詢。模糊查詢，會找到和它最接近，但比它小的那個數。因此返回的數值不正確。

修改方法：將公式改為=VLOOKUP(F2,B:D,3,)或者=VLOOKUP(F2,B:D,3,0)

— 02 —

查詢匹配的錯誤

除了引數設定錯誤之外，如果要查詢的資料來源不符合規範，也會出現錯誤。

NO.1：資料表中含有多餘的空格

如圖查詢成員的成績，陸亦可的成績能夠正確查詢，陳海的卻出錯。

錯誤原因：源資料中，為了使姓名對齊，在陳海姓名中間添加了空格。這樣使用不帶空格的“陳海”去匹配，當然查詢不到了。

NO.2：查詢物件與源資料格式不一致

小白雷哥需要透過員工工號查詢到電腦號碼。使用=VLOOKUP(G3,A2:D12,4,1) 查詢時，返回錯誤值#N/A 。

診斷分析：星爺透過他的火眼金睛，立馬就發現了問題。這是因為查詢值（11208）與查詢範圍第一列（工號）資料格式不一致導致的。在vlookup函式查詢過程中，文字型數字和數值型數字會被認為不同的字元。所以造成無法成功查詢。

解決方案：將源資料中工號一列更改為文字型別，然後再查詢。

— 03 —

單元格引用導致的錯誤

函式中的單元格引用，“混合引用”的方式是最複雜的，也是最容易出錯的。不管是引數1，還是引數2都會有這樣的問題。

如圖使用COLUMN函式與VLOOKUP函式巢狀，一次返回多列查詢值，在G2中輸入公式=VLOOKUP(F2,B2:D9,COLUMN(B1),0)，然後向下拖動複製，並向右拖動複製，但是返回的值有一部分是錯誤的。

錯誤原因：①由於第二個引數B2:D9是相對引用，所以向下複製公式後會自動更改為B3:D10,B4:D11……而F4中的陳海所在的行，不在B4:D11區域中，從而造成查詢失敗。

②而向右複製時，引數1會變為G3，因此查詢物件變為了性別，從而造成查詢失敗。

解決方法：把引數2由相對引用改為絕對引用；引數1改為混合引用。即公式為=VLOOKUP($F2,$B$2:$D$9,COLUMN(B1),0)

這樣既能確保向下複製時可以查詢不同的姓名，又能確保向右複製時查詢物件不會篡位。

這些VLOOKUP錯誤種類幾乎囊括了所有的查詢情況，如果碰到了錯誤，而你剛好有解決方案，效率豈不大增！

·END·

我也是剛學會。

這個函式的語言理解了，就容易了，其實也就是要回答這四個問題:

首先，是查什麼，

然後，是在哪兒查？這往往就是需要你用滑鼠框住一片資料。但是需要從第一問也就是你剛剛選定的查什麼那一列開始框選，一直框到第三問的那一列。

第三問，你想查那個範圍之內的第幾列資料，或者說你想獲取的資料在框住的第幾列。

最後一問就容易了，初學入門的輸一個1就直接進行精確匹配查詢好了，

反括號，搞完收工。

然後往下一拖，你會發現不對勁。問題出在哪裡呢？原來沒有對第二問，也就是那個區域進行鎖定，滑鼠往下拖的時候，區域也在往下跑。怎麼辦？選中第一個函式的公式，然後在它的第二個引數，也就是它的區域那裡按F4，（鍵盤最上面的第五個按鍵，千萬不要在公式裡面輸一個F4）給它上鎖，免得他到處逃跑。

然後再往下一拖，啊！一陣酥麻，一陣爽滑。大腿內側微微一陣痙攣。突然覺得這個回答真的是太簡單易懂了，怎麼早點不碰到呢？相見恨晚吶！痛哭流涕不止。

這滑鼠往下一拖，滿滿的都是快感，感覺拖一遍不夠。好！清除掉，再拖一遍，多享受幾遍。

我曾經試過在幾千條資訊中查詢有用的幾百條資訊。由於資訊源來自網咖下載的，有字元已被隱藏了，在查詢這一列時，就會出現返回錯誤值。我的做法是：先將該列資料複製到文字（txt格式的那個系統自帶的那個），清除隱藏字元後再複製回到原列，好笨的方法。在這理希望高手看到請留下更好的方法，謝謝！

1，VLOOKUP常見錯誤分析 - 絕少第四引數。

C15=VLOOKUP(B15,C5:F11,3)

錯誤原因：缺少第四個引數。

解釋：當缺少第四個引數或為1時表示模糊查詢，為0時表示精確查詢

正確公式:C15=VLOOKUP(B15,C5:F11,3,0)

2，VLOOKUP常見錯誤分析 - 查詢範圍中有重複值。

錯誤原因：被查詢區域（C6:C11）有重複值，有兩個officegif。

說明：VLOOKUP只返回從上到下第一次出現的值。

解決辦法：用唯一值進行查詢，比如有編號。

3，VLOOKUP常見錯誤分析 - 相對引用查詢範圍時下拉錯位。

錯誤公式：C15=VLOOKUP(B15,C6:E11,3,0)

錯誤原因：相對引用範圍“C6:E11”下拉到C17變成"C8:E13"

正確公式：D15=VLOOKUP(B15,$C$6:$E$11,3,0)

4，VLOOKUP常見錯誤分析 - 從右向左查詢。

錯誤公式：C15=VLOOKUP(B15,$B$6:$C$11,2,0)

錯誤原因：VLOOKUP不支援從右向左查詢

正確公式:D15=VLOOKUP(B15,IF({1,0},$C$6:$C$11,$B$6:$B$11),2,0)

5，VLOOKUP常見錯誤分析 - 查詢區域與被查詢區域格式不一致。

錯誤原因：查詢、被查詢區域數字格式不一致（有些事文字格式，有些事數字格式）

解決方案：用“資料/分列”功能將兩邊的格式轉為一致。

6，VLOOKUP常見錯誤分析 - 被查詢區域存在萬用字元。

錯誤原因：查詢單元格中存在萬用字元 ~

解決方案：使用SUBSTITUTE函式將~替換為~~

即D15=VLOOKUP(SUBSTITUTE(B15,"~","~~"),$B$5:$C$11,2,0)

說明：Excel中~的含義是萬用字元，若要表示文字的~，則要書寫為~~

7，VLOOKUP常見錯誤分析 - 查詢區域存在空格。

錯誤原因：單元格存在空格

解決方案：用替換功能（Ctrl+H）將空格替換掉

8，VLOOKUP常見錯誤分析 - 查詢區域存在回車字元。

錯誤原因：單查詢區域存在回車字元。

解決方案：用替換功能（Ctrl+H）將回車字元替換掉。

替換時在"查詢內容"同時按下Ctrl+回車。

9，VLOOKUP常見錯誤分析 - 第三個引數在橫向拉動時不會改變

公式：C15=VLOOKUP(B15,C5:F11,2,0)

把公式從C15複製到D15，查詢結果不正確

錯誤原因：第三個引數在橫向拉動時不會改變

解決方法：巢狀MATCH函式， 根據列表題自動返回第三個引數

公式：D16=VLOOKUP($B16,$C$5:$F$11,MATCH(C14,$C$5:$F$5,0),0)

VLOOKUP函式是工作中最常用的一種查詢函式，掌握好VLOOKUP函式能夠極大提高工作的效率。

VLOOKUP函式用於首列查詢並返回指定列的值，字母“V”表示垂直方向。

VLOOKUP函式的語法如下：

VLOOKUP（lookup_value，table_array，col_index_num，[range_lookup]）

其中，第1引數lookup_value為要搜尋的值，第2引數table_array為首列可能包含查詢值的單元格區域或陣列，第3引數col_index_num為需要從table_array中返回的匹配值的列號，第4引數range_lookup用於指定精確匹配或近似匹配模式。

當range_lookup為TRUE、被省略或使用非零數值時，表示近似匹配模式，要求table_array第一列中的值必須按升序排列，並返回小於等於lookup_value的最大值對應列的資料。當引數為FALSE時（常用數字0或保留引數前的逗號代替），表示只查詢精確匹配值，返回table_array的第一列中第一個找到的值，精確匹配模式不必對table_array第一列中的值進行排序。

如果使用精確匹配模式且第1引數為文字，則可以在第1引數中使用萬用字元問號（？）和星號（*）。VLOOKUP函式不區分字母大小寫。

案例一

A3:B7單元格區域為字母等級查詢表，表示60分以下為E級、60~69分為D級、70~79分為C級、80~89分為B級、90分以上為A級。D:G列為初二年級1班語文測驗成績表，如何根據語文成績返回其字母等級？

在H3:H13單元格區域中輸入=VLOOKUP（G3，$A$3:$B$7,2）

案例二

在Sheet1裡面如何查詢折舊明細表中對應編號下的月折舊額？（跨表查詢）

在Sheet1裡面的C2:C4單元格輸入 =VLOOKUP(A2,折舊明細表!A$2:$G$12,7,0)

案例三

如何實現萬用字元查詢？

在B2:B7區域中輸入公式=VLOOKUP(A2&"*",折舊明細表!$B$2:$G$12,6,0)

案例四

如何實現模糊查詢？

在F1:F9區域中輸入公式=VLOOKUP(E2,$A$2:$B$7,2,1)

案例五

如何透過數值查詢文字資料、透過文字查詢數值資料、同時實現數值與文字資料混合查詢？

透過數值查詢文字資料：在F3:F6區域中輸入公式=VLOOKUP(E3&"",$A$2:$C$6,3,0)

透過文字查詢數值資料：在F11:F13區域中輸入公式=VLOOKUP(--E11,$A$10:$C$14,3,0)

同時實現數值與文字資料混合查詢：在F19:F21區域中輸入公式=IF(ISNA(VLOOKUP(E19*1,$A$18:$C$22,3,0)),VLOOKUP(E19&"",$A$18:$C$22,3,0),VLOOKUP(E19*1,$A$18:$C$22,3,0))

案例六

在Excel中錄入資料資訊時，為了提高工作效率，使用者希望透過輸入資料的關鍵字後，自動顯示該記錄的其餘資訊，例如，輸入員工工號自動顯示該員工的信命，輸入物料號就能自動顯示該物料的品名、單價等。如圖所示為某單位所有員工基本資訊的資料來源表，在“2010年3月員工請假統計表”工作表中，當在A列輸入員工工號時，如何實現對應員工的姓名、身份證號、部門、職務、入職日期等資訊的自動錄入？

解決方案1：使用VLOOKUP+MATCH函式

在“2010年3月員工請假統計表”工作表中選擇B3:F8單元格區域，輸入下列公式，按【Ctrl+Enter】組合鍵結束。

=IF($A3="","",VLOOKUP($A3,員工基本資訊!$A:$H,MATCH(B$2,員工基本資訊!$2:$2,0),0))

解決方案2：HLOOKUP+MATCH函式。

在“2010年3月員工請假統計表”工作表中選擇B3:F8單元格區域，輸入下列公式，按【Ctrl+Enter】組合鍵結束

=IF($A3="","",HLOOKUP(B$2,員工基本資訊!$A$2:$H$20,MATCH($A3,員工基本資訊!$A$2:$A$20,0),0))

案例七

在使用Excel查詢和引用資料時，經常需要將文字形式的單元格地址轉換成對應應用，。如下圖所示為某超市的商品採購清單，其中又兩個供貨商提供了報價表（如供貨商A、供貨商B工作表），如何根據品名和供貨商自動查詢對應的商品單價？

選擇D3:D13單元格區域，輸入下列公式，按【Ctrl+Enter】組合鍵結束。

=VLOOKUP(B3,INDIRECT(C3&"!a:b"),2,0)

案例八

用VLOOKUP函式實現反向查詢，如下圖，如何實現透過工號來查詢姓名？

有三種實現方法：

方法一：在B8單元格輸入=VLOOKUP(A8,CHOOSE({1,2},B1:B5,A1:A5),2,0)，按ENTER鍵結束。

方法二：在B8單元格輸入=VLOOKUP(A8,IF({1,0},B1:B5,A1:A5),2,0)，按ENTER鍵結束。

方法三：在B8單元格輸入=INDEX(A1:A5,MATCH(A8,B1:B5,))，按ENTER鍵結束。

案例九

用VLOOKUP函式實現多條件查詢，如下圖，如何實現透過姓名和工號來查詢員工籍貫？

在C16單元格里面輸入=VLOOKUP(A16&B16,IF({1,0},A2:A5&B2:B5,D2:D5),2,0)，按SHIFT+CTRL+ENTER鍵結束。

案例十

用VLOOKUP函式實現批次查詢，VLOOKUP函式一般情況下只能查詢一個，那麼多項應該怎麼查詢呢？如下圖，如何把張一的消費額全部列出？

在C9：C11單元格里面輸入公式=VLOOKUP(B$9&ROW(A1),IF({1,0},$B$2:$B$6&COUNTIF(INDIRECT("b2:b"&ROW($2:$6)),B$9),$C$2:$C$6),2,)，按SHIFT+CTRL+ENTER鍵結束。

此外，VLOOKUP函式雖然容易上手使用起來確實不方便，我們可以用INDEX函式：

為了大家很好的理解index函式，先跟大家介紹一個場景軍訓佇列點名，如下圖：

全班一共站了3排12列，教官說在佇列裡面不許講話不許動，要動打報告！但是總是有人會不由自主的動一下，如上圖穿紅衣服那位，估計手痠了一直再甩手。這時候教官就要請他出列，因為不知道名字所以教官的指令為：第2排第6列的，出列！

這個指令就相當於index函式，excel表格也是一個一個單元格組成的“佇列”，要想讓哪個資料出來就用index發號指令：

INDEX（資料範圍,第幾行,第幾列):

在具體匹配的過程中我們能清楚快速的知道要匹配的值在第幾列，但是不知道在第幾行，如下表：

這時候用INDEX函式可以確定範圍，以及GMV在第3列，但是相關類目在第幾行是沒法確定的，這個時候我們需要一個MATCH函式：

MATCH（資料,資料範圍，0)，透過match函式可以判斷資料在資料範圍排在第幾位，如MATCH（"男裝"，A2:A8，0）返回的值是1:

在配上index函式就能匹配出相應的值，如上圖匹配男裝類目GMV：

=INDEX（$A2$:$D8$,MATCH(F2,$A2$:$A8$,0),3)

VLOOKUP函式引數搞不懂，總出錯，希望以下傻瓜級的講解，讓你不再糾結！

首先，考你一個傻瓜問題：叮叮幾歲？！！，你會說我怎麼知道，又有沒有參考資料。參考資料表看下圖

現在再問你叮叮幾歲？11歲！ 你需要三步分析，首先知道“叮叮”；然後在資料表中找“叮叮”；找到“叮叮”後，看第二列的年齡，你知道叮叮是11歲！

VLOOKUP函式也是這個思路回答問題的，問VLOOKUP函式 叮叮幾歲?

VLOOUP(叮叮，資料表，2) ，第一個引數就是要找的值“叮叮”，第二個引數就是有”叮叮“年齡的資料表，第三個引數”2“，就是找到”叮叮“後發現年齡在第2列。最後返回值為”11。 將VLOOUP(叮叮，資料表，2)翻譯成Excel函式格式“=VLOOKUP(A2,A2:B4,2)”寫入B7，下圖黃色單元格，返回值“11”。

再正式一點的講解：

叮叮，叫做查詢目標

有叮叮及年齡的表格，叫做查詢範圍

年齡所在的列，叫做返回值的列數

以上這些就是VLOOKUP引數，根據引數格式，VLOOKUP(查詢目標，查詢範圍，返回值的列數)，我們可以寫出函式“=VLOOKUP(A2,A2:B4,2)”

再官方一點講解：

該函式的語法規則如下：

VLOOKUP(lookup_value,table_array,col_index_num,range_lookup)

有細心的夥伴會發現，官方講解中出現了第4個引數，而之前只講了3個引數。第4個代表精確查詢或模糊查詢，聽到這裡是不是又有點暈，沒關係！這個引數不實用，暫時不需要理解太深，這裡告訴大家第4個函式的使用準則，只要遇到VLOOKUP函式必須寫第4個引數，填0就可以。就這樣記吧，保證你不犯錯！

好了，講到這裡如果你還不懂，那我真的糾結應不應該做老師了！

再考你一個傻瓜問題：喵喵幾歲？希望你能運用VLOOKUP函式給我一個官方的寫法，4個引數哦！

答案：=VLOOKUP(A4,A2:B4,2,0)，不要忘記第4個引數！

是不是太簡單了，最後一個傻瓜問題，叮叮幾歲、咚咚幾歲、喵喵幾歲，我們只要求出叮叮幾歲，利用填充，咚咚幾歲、喵喵幾歲就全部顯示出來了。

看明白了吧，但是為什麼這次第二個引數多了幾個“$”符號呢，記住：在使用填充單元格功能之前一定要把第二個引數加上“$”符號,保證準確無誤！

VLOOKUP進階高階問題：

VLOOKUP的反向查詢技巧VLOOKUP的模糊查詢應用VLOOKUP的區間查詢應用VLOOKUP的多項查詢技能

以上課程會陸續為大家講解，敬請關注！

沒有Excel2016最新版的夥伴，可以私聊回覆“2016”獲取最新版

vlookup函式是Excel的入門函式，也是Excel中最常用函式，沒有之一。

但，Vlookup函式在幾中場景下，使用起來略顯麻煩。如，自右向左查詢，橫向查詢等。

當然，Vlookup出錯率也會高點。

這裡，我就分享給大家另外一個替代Vlookup的方法，那就是Index+Match組合。

Vlookup

先來看看vlookup的用法

VLOOKUP（找什麼，在哪找，位於區域的第幾列，精確還是模糊找）

最牛查詢Index+Match組合

為何我要給大家推薦這組組合？

因為Index+Match組合靈活，簡單。你試試，相信你也會喜歡的。

INDEX(array, row_num, [column_num])

MATCH(lookup_value, lookup_array, [match_type])

別看這個公式這麼長，其實很好理解。

用match找到滿足條件的位置，然後用index定位，就這麼簡單。

這個組合，不管是自左向右，還是自右向左，動態區域查詢等場景下，用起來就是順手。

【本文示例檔案獲取方法見文末】

VLOOKUP函式非常容易出錯，錯誤原因可能讓人百思不得其解，技巧君總結了VLOOKUP函式的常見7大錯誤以及排除方法，詳情請看影片詳細瞭解吧！

示例檔案獲取方法：點選右上角紅色按鈕關注EXCEL精選技巧，然後點選技巧君頭像，傳送私信【VLOOKUP錯誤排除】即可獲取關注EXCEL精選技巧，每天學習3分鐘，堅持一個月，你將大不同！

有，三句話：找誰，在什麼地方找，找到後第幾列。1.誰就是兩張表相同的欄位，也叫關鍵字，是連結兩個表的紅娘2.在哪裡找，匹配肯定是兩張表，你就要選取另外一張表中含有關鍵字和目標值的區域，當然，你選整張表也可以，因為肯定包含關鍵字和目標值；3.另外一張表關鍵字所在的列為第一列，目標值在第幾列就寫幾，第四個引數不管，寫0即可。

引用分絕對引用和相對應用在Vlookup中經常會用到絕對引用，一定要注意它的使用方法哦

首先介紹一下公式：VLOOKUP(查詢值，查詢範圍，查詢列數，精確匹配或者近似匹配）

這裡特別注意查詢範圍的絕對引用符號“$”

很多的初學者往往忽略絕對引用的重要性導致匹配不到資料

注意兩個紅色框的查詢範圍在沒輸入$絕對引用時候發生的問題，從第7行到10行的資料出現匹配問題，原因就是在Vlookup公式下拉之前沒有新增絕對引用導致excel自動輸入公式的時候出現匹配區域錯誤

VLOOKUP函式的主要功能是精確查詢唯一值，

索引-就非常重要，目標值與源資料中的索引值，必須嚴格一致，沒有空格等等

引用的資料區域-要確定位置，不要因為下拉，改變位置，導致出錯

最後，確實找不到資料，有不想出現N/A，就使用IFERROR函式

查詢引用一般使用index+match組合，可以動態取數。比vlookup要準確性好一些，關鍵是不用分前後順序，相反，_lookup，vlookup，hlookup都需要指定列和行，表太大就要數一下效率不高。但是模糊引用資料組使用lookup還是很好很強大的

好解決，

1.最好的辦法是把格式弄好，這是做表的基本素質；

2.用iferror巢狀兩個vlookup，一個用數值V，一個用文字V。